mirror of
https://github.com/soywod/himalaya.git
synced 2024-07-03 07:55:13 +00:00
8cdeba62a1
* doc: fix blur in list msg screenshots (#181) * fix a typo in mbox arg (#245) `targetted` to `targeted` 👌🏻 * make inbox, sent and drafts folder customizable (#246) * mbox: make inbox, sent and drafts folder customizable * msg: update send handler parameters order * vim: fix extracting message ids from list (#247) The current method doesn't work because the list uses a fancy line character (`│`) as the separator, not a regular pipe character (`|`). Matching for the first number in the line instead solves the problem and will continue to work regardless of what separator is used. * add new line after printing strings (#251) * init cargo workspace (#252) * init cargo workspaces * nix: fix assets path * doc: update rtp vim plugin * vim: add error message if loading vim plugin from vim/ * init sub crates (#253) * init sub crates * doc: update readme * doc: improve main readme * doc: add links, add missing crate task * doc: update emojis * update cargo lock * implement contact completion with completefunc (#250) This allows users to define a command for contact completion with `g:himalaya_complete_contact_cmd` and trigger it with `<C-x><C-u>` when writing an email. * fix clippy lints (#255) * revert cargo workspace feature * fix nix run (#274) * replace cargo2nix by naersk * add rust-analyzer and rustfmt to nix build inputs * remove wiki from git submodules, update changelog * fix missing range when fetch fails, add more logs (#276) * add missing fix in changelog * remove blank lines and spaces from plain parts (#280) * fix watch command (#271) * remove also tabs from text parts (#280) * pin native-tls minor version (#278) * improve msg sanitization (#280) * fix mbox vim plugin telescope preview (#249) * bump version v0.5.2 * update changelog Co-authored-by: Austin Traver <austintraver@gmail.com> Co-authored-by: Jason Cox <dev@jasoncarloscox.com> Co-authored-by: Gökmen Görgen <gkmngrgn@gmail.com> Co-authored-by: Ethiraric <ethiraric@gmail.com>
88 lines
2.7 KiB
Nix
88 lines
2.7 KiB
Nix
{
|
|
description = "Command-line interface for email management";
|
|
|
|
inputs = {
|
|
utils.url = "github:numtide/flake-utils";
|
|
rust-overlay.url = "github:oxalica/rust-overlay";
|
|
naersk.url = "github:nix-community/naersk";
|
|
flake-compat = {
|
|
url = "github:edolstra/flake-compat";
|
|
flake = false;
|
|
};
|
|
};
|
|
|
|
outputs = { self, nixpkgs, utils, rust-overlay, naersk, ... }:
|
|
utils.lib.eachDefaultSystem
|
|
(system:
|
|
let
|
|
name = "himalaya";
|
|
pkgs = import nixpkgs {
|
|
inherit system;
|
|
overlays = [
|
|
rust-overlay.overlay
|
|
(self: super: {
|
|
# Because rust-overlay bundles multiple rust packages into one
|
|
# derivation, specify that mega-bundle here, so that crate2nix
|
|
# will use them automatically.
|
|
rustc = self.rust-bin.stable.latest.default;
|
|
cargo = self.rust-bin.stable.latest.default;
|
|
})
|
|
];
|
|
};
|
|
naersk-lib = naersk.lib.${system};
|
|
in
|
|
rec {
|
|
# nix build
|
|
defaultPackage = packages.${name};
|
|
packages = {
|
|
${name} = naersk-lib.buildPackage {
|
|
pname = name;
|
|
root = ./.;
|
|
nativeBuildInputs = with pkgs; [ openssl.dev pkgconfig ];
|
|
overrideMain = _: {
|
|
postInstall = ''
|
|
mkdir -p $out/share/applications/
|
|
cp assets/himalaya.desktop $out/share/applications/
|
|
'';
|
|
};
|
|
};
|
|
"${name}-vim" = pkgs.vimUtils.buildVimPluginFrom2Nix {
|
|
inherit (packages.${name}) version;
|
|
name = "${name}-vim";
|
|
src = self;
|
|
buildInputs = [ packages.${name} ];
|
|
dontConfigure = false;
|
|
configurePhase = "cd vim/";
|
|
postInstall = ''
|
|
mkdir -p $out/bin
|
|
ln -s ${packages.${name}}/bin/himalaya $out/bin/himalaya
|
|
'';
|
|
};
|
|
};
|
|
|
|
# nix run
|
|
defaultApp = apps.${name};
|
|
apps.${name} = utils.lib.mkApp {
|
|
inherit name;
|
|
drv = packages.${name};
|
|
};
|
|
|
|
# nix develop
|
|
devShell = pkgs.mkShell {
|
|
RUST_SRC_PATH = "${pkgs.rust.packages.stable.rustPlatform.rustLibSrc}";
|
|
inputsFrom = builtins.attrValues self.packages.${system};
|
|
buildInputs = with pkgs; [
|
|
cargo
|
|
cargo-watch
|
|
trunk
|
|
ripgrep
|
|
rust-analyzer
|
|
rustfmt
|
|
rnix-lsp
|
|
nixpkgs-fmt
|
|
];
|
|
};
|
|
}
|
|
);
|
|
}
|